centre	JSR getrlA
	LDX #0
	LDY #6
	JSR cfout
	JSR chkcma
	JSR getrlB
	JSR cendB
	LDX #5
	LDY #6
	JSR cfout
centr2	LDX #0
	LDY #6
	JSR calcXY
	LDX #&E0
	LDY #6
	JSR cfin
	LDX #Xcent
	LDY &53
	JSR cfout
	LDX #&E5
	LDY #6
	JSR cfin
	LDX #Ycent
	LDY &53
	JSR cfout
	RTS

variab	LDA &1B
	PHA
	JSR getchB
	CMP #'%'
	BEQ varov1
evarbk	PLA
	STA &1B
	JMP endbrk

varov1	LDA #>vartab
	STA &39
	LDA #<vartab
	STA &3A
	LDA &1B
	CLC
	ADC &19
	STA &37
	LDA &1A
	ADC #0
	STA &38
	JSR gtwrd
	BCS evarbk
	TXA
	CLC
	ADC &1B
	STA &1B
	TSX
	CPX #9
	BCS fnstok
	LDX #&FF
	TXS
	CBRK
	DFB 67
	ASC "Function level"
	BRK

fnstok	PLA
	PLA
	PLA
	PLA
	PLA
	PLA
	LDX #&1C
	LDY #&1C+zpstor
vstzp	LDA &54,X
	STA (wkpnt),Y
	DEY
	DEX
	BPL vstzp
	TSX
	TXA
	CLC
	ADC #6
	PHA
	LDA #0
	LDX #1
	JSR &FFF4
	CPX #3
	BNE ntos3b
	PLA
	CLC
	ADC #1
	PHA
ntos3b	PLA
	TAX
	TXS
	JSR callrt
	PHP
	PHA
	JSR rstzp
	LDX #&FF
	LDY #vlvarw-1
vartlp	INY
	INX
	LDA varrt,X
	STA (wkpnt),Y
	CPX #evarrt-varrt
	BNE vartlp
	LDY #errloc
	LDA (wkpnt),Y
 	STA &FD
	INY
	LDA (wkpnt),Y
	STA &FE
	PLA
	TAX
	PLA	; ACTUALLY P
	TAY
	LDA &53
	PHA
	LDA #vlvarw-1
	PHA	
	TYA
	PHA
	TXA
	PLP
	RTS



varrt	PHP
	PHA
	LDY #74
	LDA (&50),Y
	STA &FE30
	STA &F4
	PLA
	PLP
	RTS
evarrt


vartab
	ASC "BASIC"
	DFB 129
	DW varbas
	ASC "BIN$"
	DFB 153
	DW dctobn
	ASC "DEC"
	DFB 154
	DW bntodc
	ASC "ER$"
	DFB 129
	DW varerr
	ASC "FREELOC"
	DFB 129
	DW freloc
	ASC "FREEMEM"
	DFB 129
	DW fremem
	ASC "MATRIX"
	DFB 153
	DW vmat
	ASC "TH"
	DFB 129
	DW vthead
	ASC "TX"
	DFB 129
	DW vtx
	ASC "TY"
	DFB 129
	DW vty
	BRK
	BRK
	BRK

vtx	LDA #0
	STA &2C
	STA &2D
	LDY #turtx
	LDA (wkpnt),Y
	SEC
	SBC #&80
	STA &2A
	INY
	LDA (wkpnt),Y
	SBC #2
	STA &2B
vtxov	BCS vtok
	DEC &2C
	DEC &2D
vtok	LDA #&40
	STA &27
	RTS

vty	LDA #0
	STA &2C
	STA &2D
	LDY #turty
	LDA (wkpnt),Y
	SEC
	SBC #0
	STA &2A
	INY
	LDA (wkpnt),Y
	SBC #2
	STA &2B
	JMP vtxov

vthead	LDX #turth
	LDY &53
	JSR cfin
	JSR normal
	LDA #&FF
	STA &27
	RTS

vmat	JSR gtinfB
	LDA &2B
	ORA &2C
	ORA &2D
	BNE badmat
	DEC &2A
	LDA &2A
	CMP #4
	BCS badmat
	PHA
	JSR citofp
	PLA
	ASL
	ASL
	ORA &2A
	CLC
	ADC #matloc
	TAX
	LDY &53
	JSR cfin
	JSR normal
	LDA #&FF
	STA &27
	RTS

badmat	CBRK
	DFB 66
	ASC "MATRIX range"
	BRK

freloc	LDA #0
	STA &2C
	STA &2D
	LDA frmem
	STA &2A
	LDA frmem+1
	STA &2B
	JMP vtok

fremem	LDA himem
	SEC
	SBC frmem
	STA &2A
	LDA himem+1
	SBC frmem+1
	STA &2B
	LDA #0
	SBC #0
	STA &2C
	STA &2D
	JMP vtok

varbas	JSR vrsion
	SEC
	SBC #&30
	STA intA
	LDA #0
	STA intA+1
	STA intA+2
	STA intA+3
	JMP vtok

dctobn	JSR gtinfB
	LDX #0
	TXA
dcbnlp	ASL &2A
	ROL &2B
	ROL &2C
	ROL &2D
	ADC #&30
	STA &600,X
	LDA #0
	INX
	CPX #32
	BNE dcbnlp
	STX &36
	JMP evrerr

bntodc	JSR gtstfB
	LDA #0
	STA &2A
	STA &2B
	STA &2C
	STA &2D
	LDY #0
bndclp	LDA &600,Y
	PHA
	SEC
	SBC #&31
	ROL &2A
	ROL &2B
	ROL &2C
	ROL &2D
	PLA
	CMP #&32
	BCS badbin
	INY
	CPY &36
	BNE bndclp
	JMP vtok

badbin	CBRK
	DFB 57
	ASC "Bad Binary"
	BRK

varerr	LDY #errloc
	LDA (wkpnt),Y
	CLC
	ADC #1
	STA &F6
	INY
	LDA (wkpnt),Y
	ADC #0
	STA &F7
	LDX #0
vrerlp	STX &36
	JSR gterbt
	LDX &36
	STA &600,X	
	INX
	CMP #0
	BNE vrerlp
	LDA 8
	ORA 9
	BEQ evrerr
	LDY #0
	DEX
vrerl2	STX &36
	LDA vrerm,Y
	STA &600,X
	INY
	INX
	CMP #0
	BNE vrerl2
	DEX
	TXA
	PHA
	LDA 8
	STA &2A
	LDA 9
	STA &2B
	JSR decstr
	LDY #0
	PLA
	TAX
vrerl3	STX &36
	LDA &6E0,Y
	STA &600,X
	INY
	INX
	CPY &2D
	BNE vrerl3
	INC &36
evrerr	LDA #0
	STA &27
	RTS

vrerm	ASC " at line "
	BRK

gterbt	LDY #74
	LDA (&50),Y
	TAY
	JSR &FFB9
	INC &F6
	BNE gterbo
	INC &F7
gterbo	RTS

decstr	LDA #0
	STA &14
	STA &2D
	STA &37
	LDY #8
dcstl1	LDX #&30
dcstl2	LDA &2A
	SEC
	SBC decnum,Y
	PHA
	LDA &2B
	SBC decnum+1,Y
	BCC dcsto1
	STA &2B
	PLA
	STA &2A
	INX
	BNE dcstl2
dcsto1	PLA
	TXA
	CMP #&30
	BNE dcsto2
	BIT &37
	BMI dcsto2
	JMP dcsto3
dcsto2	DEC &37
	STY &2C
	LDY &2D
	STA &6E0,Y
	INC &2D
	LDY &2C
dcsto3	DEY
	DEY
	BPL dcstl1
	BIT &37
	BMI dcsto4
	LDA #&30
	STA &6E0
	INC &2D
dcsto4	RTS


gtstfB	JSR setclv
	BNE fstpm
	RTS
fstpm	JMP tpmsm


gtinfB	JSR setclv
	BEQ fstpm
	BMI egtinf
	RTS
egtinf	JMP typchk

setclv	LDY #vlvrw2
	LDX #0
stclvl	LDA stclvr,X
	STA (wkpnt),Y
	INY
	INX
	CPX #estvr-stclvr
	BNE stclvl
	JSR vrsion
	SEC
	SBC #&31
	CMP #3
	BNE vntbs4
	LDA #2
vntbs4	ASL
	CLC
	ADC #(getfsb-1)*6
	TAX
	LDY #clb+1-stclvr+vlvrw2
	LDA romcll,X
	STA (wkpnt),Y
	INY
	INX
	LDA romcll,X
	STA (wkpnt),Y
	LDY #stclrm+1-stclvr+vlvrw2
	LDA &F4
	STA (wkpnt),Y
	LDA #vlvrw2
	STA &37
	LDA wkpnt+1
	STA &38
	LDA #&FF
	STA &36
	JSR pshSTR
	JMP (&37)
rtn	PLA
	PHA
	BEQ ecvar
	JSR popSTR
	PLA
	RTS
ecvar	JSR remSTR
	PLA
	RTS

stclvr	LDY #74
	LDA (&50),Y
	STA &F4
	STA &FE30
clb	JSR 0
	PHA
stclrm	LDA #0
	STA &F4
	STA &FE30
	JMP rtn

estvr

	CHN "EXT2E"